Function: LaTeX-preview-setup

LaTeX-preview-setup is an autoloaded and byte-compiled function defined in preview.el.

Signature

(LaTeX-preview-setup)

Documentation

Hook function for embedding the preview package into AUCTeX.

This is called by LaTeX-mode-hook and changes AUCTeX variables to add the preview functionality.

Source Code

;; Defined in ~/.emacs.d/elpa/auctex-14.1.2/preview.el
;;;###autoload
(defun LaTeX-preview-setup ()
  "Hook function for embedding the preview package into AUCTeX.
This is called by `LaTeX-mode-hook' and changes AUCTeX variables
to add the preview functionality."
  ;; This has to be done only once.
  (unless (and (boundp 'LaTeX-mode-hook)
               (memq #'preview-mode-setup LaTeX-mode-hook))
    (remove-hook 'LaTeX-mode-hook #'LaTeX-preview-setup)
    (add-hook 'LaTeX-mode-hook #'preview-mode-setup)
    (define-key LaTeX-mode-map "\C-c\C-p" preview-map)
    (easy-menu-define preview-menu LaTeX-mode-map
      "This is the menu for preview-latex."
      '("Preview"
        "Generate previews"
        ["(or toggle) at point" preview-at-point]
        ["for environment" preview-environment]
        ["for section" preview-section]
        ["for region" preview-region (TeX-active-mark)]
        ["for buffer" preview-buffer]
        ["for document" preview-document]
        "---"
        "Remove previews"
        ["at point" preview-clearout-at-point]
        ["from section" preview-clearout-section]
        ["from region" preview-clearout (TeX-active-mark)]
        ["from buffer" preview-clearout-buffer]
        ["from document" preview-clearout-document]
        "---"
        "Turn preamble cache"
        ["on" preview-cache-preamble]
        ["off" preview-cache-preamble-off]
        "---"
        ("Customize"
         ["Browse options"
          (customize-group 'preview)]
         ["Extend this menu"
          (easy-menu-add-item
           nil '("Preview")
           (customize-menu-create 'preview))])
        ["Read documentation" preview-goto-info-page]
        ["Report Bug" preview-report-bug]))
    (if (eq major-mode 'LaTeX-mode)
        (preview-mode-setup))
    (unless preview-tb-icon
      (setq preview-tb-icon (preview-filter-specs preview-tb-icon-specs)))
    (when preview-tb-icon
      (define-key LaTeX-mode-map [tool-bar preview]
        `(menu-item "Preview at point" preview-at-point
                    :image ,preview-tb-icon
                    :help "Preview on/off at point"
                    :vert-only t)))))