Function: TeX-region-update

TeX-region-update is a byte-compiled function defined in tex.el.

Signature

(TeX-region-update)

Documentation

Update the TeX-region file.

Source Code

;; Defined in ~/.emacs.d/elpa/auctex-14.1.2/tex.el
(defun TeX-region-update ()
  "Update the TeX-region file."
  ;; Note that TeX-command-region-begin is not a marker when called
  ;; from TeX-command-buffer.
  (and (or (null TeX-command-region-begin)
           (markerp TeX-command-region-begin))
       (TeX-active-mark)
       (TeX-pin-region (region-beginning) (region-end)))
  (let* ((begin (or TeX-command-region-begin (region-beginning)))
         (end (or TeX-command-region-end (region-end)))
         (TeX-region-extra
          ;; Write out counter information to region.
          (concat (and (fboundp 'preview--counter-information)
                       (preview--counter-information begin))
                  TeX-region-extra)))
    (TeX-region-create (TeX-region-file TeX-default-extension)
                       (buffer-substring-no-properties begin end)
                       (file-name-nondirectory (TeX-buffer-file-name))
                       (TeX-current-offset begin))))