Function: browse-url-galeon

browse-url-galeon is an autoloaded, interactive and byte-compiled function defined in browse-url.el.gz.

This command is obsolete since 25.1.

Signature

(browse-url-galeon URL &optional NEW-WINDOW)

Documentation

Ask the Galeon WWW browser to load URL.

Default to the URL around or before point. The strings in variable browse-url-galeon-arguments are also passed to Galeon.

When called interactively, if variable browse-url-new-window-flag is non-nil, load the document in a new Galeon window, otherwise use a random existing one. A non-nil interactive prefix argument reverses the effect of browse-url-new-window-flag.

If browse-url-galeon-new-window-is-tab is non-nil, then whenever a document would otherwise be loaded in a new window, it is loaded in a new tab in an existing window instead.

When called non-interactively, optional second argument NEW-WINDOW is used instead of browse-url-new-window-flag.

Key Bindings

Source Code

;; Defined in /usr/src/emacs/lisp/net/browse-url.el.gz
;;;###autoload
(defun browse-url-galeon (url &optional new-window)
  "Ask the Galeon WWW browser to load URL.
Default to the URL around or before point.  The strings in variable
`browse-url-galeon-arguments' are also passed to Galeon.

When called interactively, if variable `browse-url-new-window-flag' is
non-nil, load the document in a new Galeon window, otherwise use a
random existing one.  A non-nil interactive prefix argument reverses
the effect of `browse-url-new-window-flag'.

If `browse-url-galeon-new-window-is-tab' is non-nil, then whenever a
document would otherwise be loaded in a new window, it is loaded in a
new tab in an existing window instead.

When called non-interactively, optional second argument NEW-WINDOW is
used instead of `browse-url-new-window-flag'."
  (declare (obsolete nil "25.1"))
  (interactive (browse-url-interactive-arg "URL: "))
  (setq url (browse-url-encode-url url))
  (let* ((process-environment (browse-url-process-environment))
         (process (apply #'start-process
			 (concat "galeon " url)
			 nil
			 browse-url-galeon-program
			 (append
			  browse-url-galeon-arguments
                          (if (browse-url-maybe-new-window new-window)
			      (if browse-url-galeon-new-window-is-tab
				  '("--new-tab")
				'("--new-window" "--noraise"))
                            '("--existing"))
                          (list url)))))
    (set-process-sentinel process
			  (lambda (process _change)
			    (browse-url-galeon-sentinel process url)))))