Function: cal-html-one-month

cal-html-one-month is a byte-compiled function defined in cal-html.el.gz.

Signature

(cal-html-one-month MONTH YEAR DIR)

Documentation

Write an HTML calendar file for numeric MONTH of YEAR in directory DIR.

Source Code

;; Defined in /usr/src/emacs/lisp/calendar/cal-html.el.gz
(defun cal-html-one-month (month year dir)
  "Write an HTML calendar file for numeric MONTH of YEAR in directory DIR."
  (let* ((d1 (calendar-absolute-from-gregorian (list month 1 year)))
         (d2 (calendar-absolute-from-gregorian
                      (list month
                            (calendar-last-day-of-month month year)
                            year)))
         (diary-list (cal-html-list-diary-entries d1 d2))
         (holiday-list (if cal-html-holidays (holiday-in-range d1 d2))))
    (with-temp-buffer
      (insert cal-html-b-document-string)
      (cal-html-insert-month-header month year)
      (cal-html-insert-agenda-days month year diary-list holiday-list)
      (insert cal-html-e-document-string)
      (write-file (expand-file-name
                   (cal-html-monthpage-name month year) dir)))))