Function: calendar-islamic-to-absolute

calendar-islamic-to-absolute is a byte-compiled function defined in cal-islam.el.gz.

Signature

(calendar-islamic-to-absolute DATE)

Documentation

Absolute date of Islamic DATE.

The absolute date is the number of days elapsed since the (imaginary) Gregorian date Sunday, December 31, 1 BC.

Source Code

;; Defined in /usr/src/emacs/lisp/calendar/cal-islam.el.gz
(defun calendar-islamic-to-absolute (date)
  "Absolute date of Islamic DATE.
The absolute date is the number of days elapsed since the (imaginary)
Gregorian date Sunday, December 31, 1 BC."
  (let* (;;(month (calendar-extract-month date))
         ;;(day (calendar-extract-day date))
         (year (calendar-extract-year date))
         (y (% year 30))
         (leap-years-in-cycle (cond ((< y 3) 0)
                                    ((< y 6) 1)
                                    ((< y 8) 2)
                                    ((< y 11) 3)
                                    ((< y 14) 4)
                                    ((< y 17) 5)
                                    ((< y 19) 6)
                                    ((< y 22) 7)
                                    ((< y 25) 8)
                                    ((< y 27) 9)
                                    (t 10))))
    (+ (calendar-islamic-day-number date) ; days so far this year
       (* (1- year) 354)                  ; days in all non-leap years
       (* 11 (/ year 30))             ; leap days in complete cycles
       leap-years-in-cycle            ; leap days this cycle
       (1- calendar-islamic-epoch)))) ; days before start of calendar