Function: calendar-mouse-view-diary-entries

calendar-mouse-view-diary-entries is an interactive and byte-compiled function defined in cal-menu.el.gz.

Signature

(calendar-mouse-view-diary-entries &optional DATE DIARY EVENT)

Documentation

Pop up menu of diary entries for mouse-selected date.

Use optional DATE and alternative file DIARY. EVENT is the event that invoked this command. Shows holidays if diary-show-holidays-flag is non-nil.

Key Bindings

Source Code

;; Defined in /usr/src/emacs/lisp/calendar/cal-menu.el.gz
(defun calendar-mouse-view-diary-entries (&optional date diary event)
  "Pop up menu of diary entries for mouse-selected date.
Use optional DATE and alternative file DIARY.  EVENT is the event
that invoked this command.  Shows holidays if `diary-show-holidays-flag'
is non-nil."
  (interactive "i\ni\ne")
  (let* ((date (or date (calendar-cursor-to-date nil event)))
         (diary-file (or diary diary-file))
         (diary-list-include-blanks nil)
         (diary-entries (mapcar (lambda (x) (split-string (cadr x) "\n"))
                                (diary-list-entries date 1 'list-only)))
         (holidays (if diary-show-holidays-flag
                       (calendar-check-holidays date)))
         (title (format "Diary entries%s for %s"
                        (if diary (format " from %s" diary) "")
                        (calendar-date-string date)))
         (selection (cal-menu-x-popup-menu event title
                      (mapcar (lambda (x) (list (concat "     " x))) holidays)
                      (if holidays
                          (list "--shadow-etched-in" "--shadow-etched-in"))
                      (if diary-entries
                          (mapcar 'list (apply 'append diary-entries))
                        '("None")))))
    (and selection (call-interactively selection))))