Function: calendar-sunrise-sunset-month

calendar-sunrise-sunset-month is an autoloaded, interactive and byte-compiled function defined in solar.el.gz.

Signature

(calendar-sunrise-sunset-month &optional EVENT)

Documentation

Local time of sunrise and sunset for month under cursor or at EVENT.

Key Bindings

Source Code

;; Defined in /usr/src/emacs/lisp/calendar/solar.el.gz
;;;###cal-autoload
(defun calendar-sunrise-sunset-month (&optional event)
  "Local time of sunrise and sunset for month under cursor or at EVENT."
  (interactive (list last-nonmenu-event))
  (or (and calendar-latitude calendar-longitude calendar-time-zone)
      (solar-setup))
  (let* ((date (calendar-cursor-to-date t event))
         (month (car date))
         (year (nth 2 date))
         (last (calendar-last-day-of-month month year))
         (title (format "Sunrise/sunset times for %s %d at %s"
                        (calendar-month-name month) year
                        (eval calendar-location-name))))
    (calendar-in-read-only-buffer solar-sunrises-buffer
      (calendar-set-mode-line title)
      (insert title ":\n\n")
      (dotimes (i last)
        (setq date (list month (1+ i) year))
        (insert (format "%s %2d: " (calendar-month-name month t) (1+ i))
                (solar-sunrise-sunset-string date t) "\n")))))