Function: cider-repl--display-image

cider-repl--display-image is a byte-compiled function defined in cider-repl.el.

Signature

(cider-repl--display-image BUFFER IMAGE &optional SHOW-PREFIX BOL)

Documentation

Insert IMAGE into BUFFER at the current point.

For compatibility with the rest of CIDER's REPL machinery, supports SHOW-PREFIX and BOL.

Source Code

;; Defined in ~/.emacs.d/elpa/cider-20260414.1619/cider-repl.el
(defun cider-repl--display-image (buffer image &optional show-prefix bol)
  "Insert IMAGE into BUFFER at the current point.

For compatibility with the rest of CIDER's REPL machinery, supports
SHOW-PREFIX and BOL."
  (with-current-buffer buffer
    (save-excursion
      (cider-save-marker cider-repl-output-start
        (goto-char cider-repl-output-end)
        (when (and bol (not (bolp)))
          (insert-before-markers "\n"))
        (when show-prefix
          (insert-before-markers
           (propertize cider-repl-result-prefix 'font-lock-face 'font-lock-comment-face)))
        ;; The below is inlined from `insert-image' and changed to use
        ;; `insert-before-markers' rather than `insert'
        (let ((start (point))
              (props (nconc `(display ,image rear-nonsticky (display))
                            (when (boundp 'image-map)
                              `(keymap ,image-map)))))
          (insert-before-markers " ")
          (add-text-properties start (point) props)))))
  t)