Function: custom-reset-standard-save-and-update

custom-reset-standard-save-and-update is a byte-compiled function defined in cus-edit.el.gz.

Signature

(custom-reset-standard-save-and-update)

Documentation

Save settings and redraw after erasing customizations.

Source Code

;; Defined in /usr/src/emacs/lisp/cus-edit.el.gz
;; The next function was excerpted from `custom-variable-reset-standard'
;; and `custom-face-reset-standard' and is used to avoid calling
;; `custom-save-all' repeatedly (and thus saving settings to file one by
;; one) when erasing all customizations.
(defun custom-reset-standard-save-and-update ()
  "Save settings and redraw after erasing customizations."
  (when (or (and custom-reset-standard-variables-list
		 (not (eq custom-reset-standard-variables-list  '(t))))
	    (and custom-reset-standard-faces-list
		 (not (eq custom-reset-standard-faces-list '(t)))))
    ;; Save settings to file.
    (custom-save-all)
    ;; Set state of and redraw variables.
    (dolist (widget custom-reset-standard-variables-list)
      (unless (eq widget t)
	(widget-put widget :custom-state 'unknown)
	(custom-redraw widget)))
    ;; Set state of and redraw faces.
    (dolist (widget custom-reset-standard-faces-list)
      (unless (eq widget t)
	(let* ((symbol (widget-value widget))
	       (child (car (widget-get widget :children)))
	       (comment-widget (widget-get widget :comment-widget)))
	  (put symbol 'face-comment nil)
	  (widget-value-set child
			    (custom-pre-filter-face-spec
			     (list (list t (custom-face-attributes-get
					    symbol nil)))))
	  ;; This call manages the comment visibility
	  (widget-value-set comment-widget "")
	  (custom-face-state-set widget)
	  (custom-redraw-magic widget))))))