Function: customize-group

customize-group is an autoloaded, interactive and byte-compiled function defined in cus-edit.el.gz.

Signature

(customize-group &optional GROUP OTHER-WINDOW)

Documentation

Customize GROUP, which must be a customization group.

If OTHER-WINDOW is non-nil, display in another window.

Probably introduced at or before Emacs version 20.1.

Key Bindings

Source Code

;; Defined in /usr/src/emacs/lisp/cus-edit.el.gz
;;;###autoload
(defun customize-group (&optional group other-window)
  "Customize GROUP, which must be a customization group.
If OTHER-WINDOW is non-nil, display in another window."
  (interactive (list (customize-read-group)))
  (when (stringp group)
    (if (string-equal "" group)
	(setq group 'emacs)
      (setq group (intern group))))
  (let ((name (format "*Customize Group: %s*"
		      (custom-unlispify-tag-name group))))
    (cond
     ((null (get-buffer name))
      (funcall (if other-window
		   'custom-buffer-create-other-window
		 'custom-buffer-create)
	       (list (list group 'custom-group))
	       name
	       (concat " for group "
		       (custom-unlispify-tag-name group))))
     (other-window
      (switch-to-buffer-other-window name))
     (t
      (pop-to-buffer-same-window name)))))