Function: dired-goto-subdir

dired-goto-subdir is an autoloaded, interactive and byte-compiled function defined in dired-aux.el.gz.

Signature

(dired-goto-subdir DIR)

Documentation

Go to end of header line of DIR in this dired buffer.

Return value of point on success, otherwise return nil. The next char is \n.

Key Bindings

Source Code

;; Defined in /usr/src/emacs/lisp/dired-aux.el.gz
;;;###autoload
(defun dired-goto-subdir (dir)
  "Go to end of header line of DIR in this dired buffer.
Return value of point on success, otherwise return nil.
The next char is \\n."
  (interactive
   (prog1				; let push-mark display its message
       (list (expand-file-name
	      (completing-read "Goto in situ directory: " ; prompt
			       dired-subdir-alist ; table
			       nil	; predicate
			       t	; require-match
			       (dired-current-directory))))
     (push-mark)))
  (setq dir (file-name-as-directory dir))
  (let ((elt (assoc dir dired-subdir-alist)))
    (and elt
         (goto-char (cdr elt))
	 ;; dired-subdir-hidden-p and dired-add-entry depend on point being
	 ;; at \n after this function succeeds.
	 (progn (end-of-line)
		(point)))))