Function: enriched-encode

enriched-encode is an autoloaded and byte-compiled function defined in enriched.el.gz.

Signature

(enriched-encode FROM TO ORIG-BUF)

Source Code

;; Defined in /usr/src/emacs/lisp/textmodes/enriched.el.gz
;;;
;;; Encoding Files
;;;

;;;###autoload
(defun enriched-encode (from to orig-buf)
  (if enriched-verbose (message "Enriched: encoding document..."))
  (let ((inhibit-read-only t)
	(inhibit-point-motion-hooks t))
    (save-restriction
      (narrow-to-region from to)
      (delete-to-left-margin)
      (unjustify-region)
      (goto-char from)
      (format-replace-strings '(("<" . "<<")))
      (format-insert-annotations
       (format-annotate-region from (point-max) enriched-translations
			       'enriched-make-annotation enriched-ignore))
      (goto-char from)
      (insert (if (stringp enriched-initial-annotation)
		  enriched-initial-annotation
		(save-excursion
		  ;; Eval this in the buffer we are annotating.  This
		  ;; fixes a bug which was saving incorrect File-Width
		  ;; information, since we were looking at local
		  ;; variables in the wrong buffer.
		  (if orig-buf (set-buffer orig-buf))
		  (funcall enriched-initial-annotation))))
      (enriched-map-property-regions 'hard
	(lambda (v b _e)
	  (if (and v (= ?\n (char-after b)))
	      (progn (goto-char b) (insert "\n"))))
	(point) nil)
      (if enriched-verbose (message nil))
      ;; Return new end.
      (point-max))))