Function: erc-nickserv-identify

erc-nickserv-identify is an autoloaded, interactive and byte-compiled function defined in erc-services.el.gz.

Signature

(erc-nickserv-identify &optional PASSWORD NICK)

Documentation

Identify to NickServ immediately.

Identification will either use NICK or the current nick if not provided, and some password obtained through erc-nickserv-get-password (which see). If no password can be found, an error is reported through erc-error.

Interactively, the user will be prompted for NICK, an empty string meaning to default to the current nick.

Returns t if the identify message could be sent, nil otherwise.

Key Bindings

Source Code

;; Defined in /usr/src/emacs/lisp/erc/erc-services.el.gz
;;;###autoload
(defun erc-nickserv-identify (&optional password nick)
  "Identify to NickServ immediately.
Identification will either use NICK or the current nick if not
provided, and some password obtained through
`erc-nickserv-get-password' (which see).  If no password can be
found, an error is reported through `erc-error'.

Interactively, the user will be prompted for NICK, an empty
string meaning to default to the current nick.

Returns t if the identify message could be sent, nil otherwise."
  (interactive
   (list
    nil
    (read-from-minibuffer "Nickname: " nil nil nil
                          'erc-nick-history-list (erc-current-nick))))
  (unless (and nick (not (string= nick "")))
    (setq nick (erc-current-nick)))
  (unless password
    (setq password (erc-nickserv-get-password nick)))
  (if password
      (erc-nickserv-send-identify nick password)
    (erc-error "Cannot find a password for nickname %s"
               nick)
    nil))