Function: global-ede-mode

global-ede-mode is an autoloaded, interactive and byte-compiled function defined in ede.el.gz.

Signature

(global-ede-mode &optional ARG)

Documentation

Toggle global EDE (Emacs Development Environment) mode.

This is a minor mode. If called interactively, toggle the Global Ede mode mode. If the prefix argument is positive, enable the mode, and if it is zero or negative, disable the mode.

If called from Lisp, toggle the mode if ARG is toggle. Enable the mode if ARG is nil, omitted, or is a positive number. Disable the mode if ARG is a negative number.

To check whether the minor mode is enabled in the current buffer, evaluate (default-value \=global-ede-mode)'.

The mode's hook is called both when the mode is enabled and when it is disabled.

This global minor mode enables ede-minor-mode(var)/ede-minor-mode(fun) in all buffers in an EDE controlled project.

Probably introduced at or before Emacs version 23.2.

Key Bindings

Source Code

;; Defined in /usr/src/emacs/lisp/cedet/ede.el.gz
;;;###autoload
(define-minor-mode global-ede-mode
  "Toggle global EDE (Emacs Development Environment) mode.

This global minor mode enables `ede-minor-mode' in all buffers in
an EDE controlled project."
  :global t
  (if global-ede-mode
      ;; Turn on global-ede-mode
      (progn
	(if semantic-mode
	    (define-key cedet-menu-map [cedet-menu-separator] '("--")))
	(add-hook 'semanticdb-project-predicate-functions #'ede-directory-project-p)
	(add-hook 'semanticdb-project-root-functions #'ede-toplevel-project-or-nil)
	(add-hook 'ecb-source-path-functions #'ede-ecb-project-paths)
	;; Append our hook to the end.  This allows mode-local to finish
	;; it's stuff before we start doing misc file loads, etc.
	(add-hook 'find-file-hook #'ede-turn-on-hook t)
	(add-hook 'dired-mode-hook #'ede-turn-on-hook)
	(add-hook 'kill-emacs-hook #'ede-save-cache)
	(ede-load-cache)
	(ede-reset-all-buffers))
    ;; Turn off global-ede-mode
    (define-key cedet-menu-map [cedet-menu-separator] nil)
    (remove-hook 'semanticdb-project-predicate-functions #'ede-directory-project-p)
    (remove-hook 'semanticdb-project-root-functions #'ede-toplevel-project-or-nil)
    (remove-hook 'ecb-source-path-functions #'ede-ecb-project-paths)
    (remove-hook 'find-file-hook #'ede-turn-on-hook)
    (remove-hook 'dired-mode-hook #'ede-turn-on-hook)
    (remove-hook 'kill-emacs-hook #'ede-save-cache)
    (ede-save-cache)
    (ede-reset-all-buffers)))