Function: gnus-article-browse-delete-temp-files

gnus-article-browse-delete-temp-files is a byte-compiled function defined in gnus-art.el.gz.

Signature

(gnus-article-browse-delete-temp-files &optional HOW)

Documentation

Delete temp-files created by gnus-article-browse-html-parts.

Source Code

;; Defined in /usr/src/emacs/lisp/gnus/gnus-art.el.gz
;; Cf. mm-postponed-undisplay-list / mm-destroy-postponed-undisplay-list.

(defun gnus-article-browse-delete-temp-files (&optional how)
  "Delete temp-files created by `gnus-article-browse-html-parts'."
  (when (and gnus-article-browse-html-temp-list
	     (progn
	       (or how (setq how gnus-article-browse-delete-temp))
	       (if (eq how 'ask)
		   (let ((files (length gnus-article-browse-html-temp-list)))
		     (or (gnus-y-or-n-p
			  (if (= files 1)
			      "Delete the temporary HTML file? "
			    (format "Delete all %s temporary HTML files? "
				    files)))
			 (setq gnus-article-browse-html-temp-list nil)))
		 how)))
    (dolist (file gnus-article-browse-html-temp-list)
      (cond ((file-directory-p file)
	     (when (or (not (eq how 'file))
		       (gnus-y-or-n-p
			(format-message
			 "Delete temporary HTML file(s) in directory `%s'? "
			 (file-name-as-directory file))))
	       (gnus-delete-directory file)))
	    ((file-exists-p file)
	     (when (or (not (eq how 'file))
		       (gnus-y-or-n-p
			(format "Delete temporary HTML file `%s'? " file)))
	       (delete-file file)))))
    ;; Also remove file from the list when not deleted or if file doesn't
    ;; exist anymore.
    (setq gnus-article-browse-html-temp-list nil))
  gnus-article-browse-html-temp-list)