Function: gnus-diary-update-group-parameters

gnus-diary-update-group-parameters is a byte-compiled function defined in gnus-diary.el.gz.

Signature

(gnus-diary-update-group-parameters GROUP)

Source Code

;; Defined in /usr/src/emacs/lisp/gnus/gnus-diary.el.gz
;; Group parameters autosetting =============================================

(defun gnus-diary-update-group-parameters (group)
  ;; Ensure that nndiary groups have convenient group parameters:
  ;; - a posting style containing X-Diary headers
  ;; - a nice summary line format
  ;; - NNDiary specific sorting by schedule functions
  ;; In general, try not to mess with what the user might have modified.

  ;; Posting style:
  (let ((posting-style (gnus-group-get-parameter group 'posting-style t))
	(headers nndiary-headers)
	header)
    (while headers
      (setq header (format "X-Diary-%s" (caar headers))
	    headers (cdr headers))
      (unless (assoc header posting-style)
	(setq posting-style (append posting-style (list (list header "*"))))))
    (gnus-group-set-parameter group 'posting-style posting-style))
  ;; Summary line format:
  (unless (gnus-group-get-parameter group 'gnus-summary-line-format t)
    (gnus-group-set-parameter group 'gnus-summary-line-format
			      `(,gnus-diary-summary-line-format)))
  ;; Sorting by schedule:
  (unless (gnus-group-get-parameter group 'gnus-article-sort-functions)
    (gnus-group-set-parameter group 'gnus-article-sort-functions
			      '((append gnus-article-sort-functions
					(list
					 'gnus-article-sort-by-schedule)))))
  (unless (gnus-group-get-parameter group 'gnus-thread-sort-functions)
    (gnus-group-set-parameter group 'gnus-thread-sort-functions
			      '((append gnus-thread-sort-functions
					(list
					 'gnus-thread-sort-by-schedule))))))