Function: gnus-message-search-citation-line

gnus-message-search-citation-line is a byte-compiled function defined in gnus-cite.el.gz.

Signature

(gnus-message-search-citation-line LIMIT)

Documentation

Search for a cited line and set match data accordingly.

Returns nil if there is no such line before LIMIT, t otherwise.

Source Code

;; Defined in /usr/src/emacs/lisp/gnus/gnus-cite.el.gz
(defun gnus-message-search-citation-line (limit)
  "Search for a cited line and set match data accordingly.
Returns nil if there is no such line before LIMIT, t otherwise."
  (when (re-search-forward gnus-message-cite-prefix-regexp limit t)
    (let ((cdepth (min (length (apply #'concat
				      (split-string
				       (match-string-no-properties 0)
				       "[\t [:alnum:]]+")))
		       gnus-message-max-citation-depth))
	  (mlist (make-list (* (1+ gnus-message-max-citation-depth) 2) nil))
	  (start (point-at-bol))
	  (end (point-at-eol)))
      (setcar mlist start)
      (setcar (cdr mlist) end)
      (setcar (nthcdr (* cdepth 2) mlist) start)
      (setcar (nthcdr (1+ (* cdepth 2)) mlist) end)
      (set-match-data mlist))
    t))