Function: gnus-summary-limit-to-age

gnus-summary-limit-to-age is an interactive and byte-compiled function defined in gnus-sum.el.gz.

Signature

(gnus-summary-limit-to-age AGE &optional YOUNGER-P)

Documentation

Limit the summary buffer to articles that are older than (or equal) AGE days.

If YOUNGER-P (the prefix) is non-nil, limit the summary buffer to articles that are younger than AGE days.

Key Bindings

Source Code

;; Defined in /usr/src/emacs/lisp/gnus/gnus-sum.el.gz
(defun gnus-summary-limit-to-age (age &optional younger-p)
  "Limit the summary buffer to articles that are older than (or equal) AGE days.
If YOUNGER-P (the prefix) is non-nil, limit the summary buffer to
articles that are younger than AGE days."
  (interactive
   (let ((younger current-prefix-arg)
	 (days-got nil)
	 days)
     (while (not days-got)
       (setq days (if younger
		      (read-string "Limit to articles younger than (in days, older when negative): ")
		    (read-string
		     "Limit to articles older than (in days, younger when negative): ")))
       (when (> (length days) 0)
	 (setq days (read days)))
       (if (numberp days)
	   (progn
	     (setq days-got t)
	     (when (< days 0)
	       (setq younger (not younger))
	       (setq days (* days -1))))
	 (message "Please enter a number.")
	 (sleep-for 1)))
     (list days younger))
   gnus-summary-mode)
  (prog1
      (let ((data gnus-newsgroup-data)
	    (cutoff (days-to-time age))
	    articles d date is-younger)
	(while (setq d (pop data))
	  (when (and (mail-header-p (gnus-data-header d))
		     (setq date (mail-header-date (gnus-data-header d))))
	    (setq is-younger (time-less-p
			      (time-since (gnus-date-get-time date))
			      cutoff))
	    (when (if younger-p
		      is-younger
		    (not is-younger))
	      (push (gnus-data-number d) articles))))
	(gnus-summary-limit (nreverse articles)))
    (gnus-summary-position-point)))