Function: gnus-summary-resend-message-insert-gcc

gnus-summary-resend-message-insert-gcc is a byte-compiled function defined in gnus-msg.el.gz.

Signature

(gnus-summary-resend-message-insert-gcc)

Documentation

Insert Gcc header according to gnus-gcc-self-resent-messages.

Source Code

;; Defined in /usr/src/emacs/lisp/gnus/gnus-msg.el.gz
(defun gnus-summary-resend-message-insert-gcc ()
  "Insert Gcc header according to `gnus-gcc-self-resent-messages'."
  (gnus-inews-insert-gcc)
  (let ((gcc (message-unquote-tokens
	       (message-tokenize-header (mail-fetch-field "gcc" nil t)
					" ,")))
	(self (with-current-buffer gnus-summary-buffer
		gnus-gcc-self-resent-messages)))
    (message-remove-header "gcc")
    (when gcc
      (goto-char (point-max))
      (cond ((eq self 'none))
	    ((eq self t)
	     (insert "Gcc: \"" gnus-newsgroup-name "\"\n"))
	    ((stringp self)
	     (insert "Gcc: "
		     (if (string-search " " self)
			 (concat "\"" self "\"")
		       self)
		     "\n"))
	    ((null self)
	     (insert "Gcc: " (mapconcat #'identity gcc ", ") "\n"))
	    ((eq self 'no-gcc-self)
	     (when (setq gcc (delete
			      gnus-newsgroup-name
			      (delete (concat "\"" gnus-newsgroup-name "\"")
				      gcc)))
	       (insert "Gcc: " (mapconcat #'identity gcc ", ") "\n")))))))