Function: hangul-to-hanja-char

hangul-to-hanja-char is a byte-compiled function defined in hanja-util.el.gz.

Signature

(hangul-to-hanja-char CHAR)

Documentation

Show the list of hanja characters converted from CHAR.

The value is a hanja character that is selected interactively.

Source Code

;; Defined in /usr/src/emacs/lisp/language/hanja-util.el.gz
(defun hangul-to-hanja-char (char)
  "Show the list of hanja characters converted from CHAR.
The value is a hanja character that is selected interactively."
  (hanja-init-load)
  (let ((echo-keystrokes 0)
        (input-method-function nil))
    (setq hanja-conversions
          (vector
           0 0
           ;; Filter characters that can not be decoded.
           ;; Maybe it can not represent characters in current terminal coding.
           (hanja-filter (lambda (x) (car x))
                         (mapcar (lambda (c)
                                   (if (listp c)
                                       (cons (decode-char 'ucs (car c)) (cdr c))
				     (list (decode-char 'ucs c))))
                                 (aref hanja-table char)))))
    (unwind-protect
	(when (aref hanja-conversions 2)
	  (catch 'exit-input-loop
	    (while t
	      (hanja-list-show)
	      (let* ((seq (read-key-sequence nil))
		     (cmd (lookup-key hanja-keymap seq)))
		(if (functionp cmd)
		    (funcall cmd)
		  (setq unread-command-events
                        (nconc (listify-key-sequence seq)
                               unread-command-events))
		  (throw 'exit-input-loop nil))))))
      (setq hanja-conversions nil))))