Function: he--all-buffers

he--all-buffers is a byte-compiled function defined in hippie-exp.el.gz.

Signature

(he--all-buffers OLD BEG-FUNCTION SEARCH-FUNCTION)

Source Code

;; Defined in /usr/src/emacs/lisp/hippie-exp.el.gz
(defun he--all-buffers (old beg-function search-function)
  (let ((expansion ())
        (buf (current-buffer))
        (only-buffers hippie-expand-only-buffers)
        (ignore-buffers hippie-expand-ignore-buffers)
        (orig-case-fold-search case-fold-search))
    (if (not old)
        (progn
	  (he-init-string (funcall beg-function) (point))
	  (setq he-search-bufs (buffer-list))
	  (setq he-searched-n-bufs 0)
	  (set-marker he-search-loc 1 (car he-search-bufs))))

    (if (not (equal he-search-string ""))
	(while (and he-search-bufs
		    (not expansion)
		    (or (not hippie-expand-max-buffers)
                        (< he-searched-n-bufs hippie-expand-max-buffers)))
          (set-buffer (car he-search-bufs))
          (if (and (not (eq (current-buffer) buf))
                   (if only-buffers
                       (he-buffer-member only-buffers)
                     (not (he-buffer-member ignore-buffers))))
              (save-excursion
                (save-restriction
                  (if hippie-expand-no-restriction
		      (widen))
		  (goto-char he-search-loc)
		  (setq expansion
			(let ((case-fold-search orig-case-fold-search))
			  (funcall search-function he-search-string)))
		  (set-marker he-search-loc (point))
		  (if (not expansion)
		      (progn
			(setq he-search-bufs (cdr he-search-bufs))
			(setq he-searched-n-bufs (1+ he-searched-n-bufs))
			(set-marker he-search-loc 1 (car he-search-bufs))))))
	    (setq he-search-bufs (cdr he-search-bufs))
	    (set-marker he-search-loc 1 (car he-search-bufs)))))

    (set-buffer buf)
    (if (not expansion)
	(progn
	  (if old (he-reset-string))
	  ())
      (progn
        (he-substitute-string expansion t)
        t))))