Function: help-fns--mention-shortdoc-groups

help-fns--mention-shortdoc-groups is a byte-compiled function defined in help-fns.el.gz.

Signature

(help-fns--mention-shortdoc-groups OBJECT)

Source Code

;; Defined in /usr/src/emacs/lisp/help-fns.el.gz
(defun help-fns--mention-shortdoc-groups (object)
  (require 'shortdoc)
  (when-let ((groups (and (symbolp object)
                          (shortdoc-function-groups object))))
    (let ((start (point))
          (times 0))
      (with-current-buffer standard-output
        (insert "  Other relevant functions are documented in the ")
        (mapc
         (lambda (group)
           (when (> times 0)
             (insert (if (= times (1- (length groups)))
                         " and "
                       ", ")))
           (setq times (1+ times))
           (insert-text-button
            (symbol-name group)
            'action (lambda (_)
                      (shortdoc-display-group group object))
            'follow-link t
            'help-echo (purecopy "mouse-1, RET: show documentation group")))
         groups)
        (insert (if (= (length groups) 1)
                    " group.\n"
                  " groups.\n")))
      (save-restriction
        (narrow-to-region start (point))
        (fill-region-as-paragraph (point-min) (point-max))
        (goto-char (point-max))))))