Function: holiday-greek-orthodox-easter

holiday-greek-orthodox-easter is a byte-compiled function defined in holidays.el.gz.

Signature

(holiday-greek-orthodox-easter &optional N STRING)

Documentation

Date of Nth day after Easter (named STRING), if visible in calendar window.

It is calculated according to the rule of the Council of Nicaea. Negative values of N are interpreted as days before Easter. STRING is used purely for display purposes. The return value has the form ((MONTH DAY YEAR) STRING), where the date is that of the Nth day before or after Easter.

For backwards compatibility, if this function is called with no arguments, it returns the date of Pascha (Greek Orthodox Easter).

Probably introduced at or before Emacs version 25.1.

Source Code

;; Defined in /usr/src/emacs/lisp/calendar/holidays.el.gz
(defun holiday-greek-orthodox-easter (&optional n string)
  "Date of Nth day after Easter (named STRING), if visible in calendar window.
It is calculated according to the rule of the Council of Nicaea.
Negative values of N are interpreted as days before Easter.
STRING is used purely for display purposes.  The return value has
the form ((MONTH DAY YEAR) STRING), where the date is that of the
Nth day before or after Easter.

For backwards compatibility, if this function is called with no
arguments, it returns the date of Pascha (Greek Orthodox Easter)."
  (let* ((m displayed-month)
         (y displayed-year)
         (julian-year (progn
                        (calendar-increment-month m y 1)
                        (calendar-extract-year
                         (calendar-julian-from-absolute
                          (calendar-absolute-from-gregorian
                           (list m (calendar-last-day-of-month m y) y))))))
         (shifted-epact                 ; age of moon for April 5
          (% (+ 14
                (* 11 (% julian-year 19)))
             30))
         (paschal-moon      ; day after full moon on or after March 21
          (- (calendar-julian-to-absolute (list 4 19 julian-year))
             shifted-epact))
	 (abs-easter (calendar-dayname-on-or-before 0 (+ paschal-moon 7)))
	 (greg (calendar-gregorian-from-absolute (+ abs-easter (or n 0)))))
    (if (calendar-date-is-visible-p greg)
	(list (list greg (or string "Pascha (Greek Orthodox Easter)"))))))