Function: info-lookup-completions-at-point

info-lookup-completions-at-point is a byte-compiled function defined in info-look.el.gz.

Signature

(info-lookup-completions-at-point TOPIC MODE)

Documentation

Try to complete a help item.

Source Code

;; Defined in /usr/src/emacs/lisp/info-look.el.gz
(defun info-lookup-completions-at-point (topic mode)
  "Try to complete a help item."
  (or mode (setq mode (info-lookup-select-mode)))
  (when (info-lookup->mode-value topic mode)
    (let ((modes (info-lookup-quick-all-modes topic mode))
          (start (point))
          try)
      (while (and (not try) modes)
        (setq mode (car modes)
              modes (cdr modes)
              try (info-lookup-guess-default* topic mode))
        (goto-char start))
      (when try
        (let ((completions (info-lookup->completions topic mode)))
          (when completions
            (when (info-lookup->ignore-case topic mode)
              (setq completions
                    (lambda (string pred action)
                      (let ((completion-ignore-case t))
                        (complete-with-action
                         action completions string pred)))))
            (save-excursion
              ;; Find the original symbol and zap it.
              (end-of-line)
              (while (and (search-backward try nil t)
                          (< start (point))))
              (list (match-beginning 0) (match-end 0) completions
                    :exclusive 'no))))))))