Function: japanese-LaTeX-guess-engine

japanese-LaTeX-guess-engine is a byte-compiled function defined in tex-jp.el.

Signature

(japanese-LaTeX-guess-engine)

Documentation

Guess Japanese TeX engine and set it to TeX-engine.

Document class and its option are taken into account. Do not overwrite the value already set locally.

Source Code

;; Defined in ~/.emacs.d/elpa/auctex-14.1.2/tex-jp.el
(defun japanese-LaTeX-guess-engine ()
  "Guess Japanese TeX engine and set it to `TeX-engine'.
Document class and its option are taken into account.  Do not
overwrite the value already set locally."
  ;; `TeX-engine' may be set by the file local variable or by the menu
  ;; Command->TeXing Options manually.  Don't override the user
  ;; preference set in such ways.
  (unless (local-variable-p 'TeX-engine (current-buffer))
    (TeX-engine-set
     (cond
      ((TeX-match-style "\\`u[jt]\\(?:article\\|report\\|book\\)\\'")
       'uptex)
      ((TeX-match-style "\\`[jt]s?\\(?:article\\|report\\|book\\)\\'")
       (if (LaTeX-match-class-option "\\`uplatex\\'")
           'uptex 'ptex))
      ((TeX-match-style "\\`j-\\(?:article\\|report\\|book\\)\\'")
       'jtex)
      (t japanese-TeX-engine-default)))))