Function: landmark

landmark is an interactive and byte-compiled function defined in landmark.el.gz.

Signature

(landmark PARG)

Documentation

Start or resume an Landmark game.

If a game is in progress, this command allows you to resume it. Here is the relation between prefix args and game options:

prefix arg | robot is auto-started | weights are saved from last game
---------------------------------------------------------------------
none / 1 | yes | no
       2 | yes | yes
       3 | no | yes
       4 | no | no

You start by moving to a square and typing M-x landmark-start-robot (landmark-start-robot), if you did not use a prefix arg to ask for automatic start. Use C-h m (describe-mode) for more info.

Probably introduced at or before Emacs version 20.1.

Key Bindings

Source Code

;; Defined in /usr/src/emacs/lisp/obsolete/landmark.el.gz
;;;###autoload
(defun landmark (parg)
  "Start or resume an Landmark game.
If a game is in progress, this command allows you to resume it.
Here is the relation between prefix args and game options:

prefix arg | robot is auto-started | weights are saved from last game
---------------------------------------------------------------------
none / 1   | yes                   | no
       2   | yes                   | yes
       3   | no                    | yes
       4   | no                    | no

You start by moving to a square and typing \\[landmark-start-robot],
if you did not use a prefix arg to ask for automatic start.
Use \\[describe-mode] for more info."
  (interactive "p")

  (setf landmark-n nil landmark-m nil)
  (landmark-switch-to-window)
  (cond
   (landmark-emacs-is-computing
    (landmark-crash-game))
   ((or (not landmark-game-in-progress)
	(<= landmark-number-of-moves 2))
    (let ((max-width (landmark-max-width))
	  (max-height (landmark-max-height)))
      (or landmark-n (setq landmark-n max-width))
      (or landmark-m (setq landmark-m max-height))
      (cond ((< landmark-n 1)
	     (error "I need at least 1 column"))
	    ((< landmark-m 1)
	     (error "I need at least 1 row"))
	    ((> landmark-n max-width)
	     (error "I cannot display %d columns in that window" landmark-n)))
      (if (and (> landmark-m max-height)
	       (not (eq landmark-m landmark-saved-board-height))
	       ;; Use EQ because SAVED-BOARD-HEIGHT may be nil
	       (not (y-or-n-p (format "Do you really want %d rows? " landmark-m))))
	  (setq landmark-m max-height)))
    (if landmark-one-moment-please
	(message "One moment, please..."))
    (landmark-start-game landmark-n landmark-m)
    (apply #'landmark-init
	   (cond
	    ((= parg 1)  '(t nil))
	    ((= parg 2)  '(t t))
	    ((= parg 3)  '(nil t))
	    ((= parg 4)  '(nil nil))
	    (t '(nil t)))))))