Function: llama-fontify-mode

llama-fontify-mode is an autoloaded, interactive and byte-compiled function defined in llama.el.

Signature

(llama-fontify-mode &optional ARG)

Documentation

In Emacs Lisp mode, highlight the ## macro and its special arguments.

This is a minor mode. If called interactively, toggle the Llama-Fontify mode mode. If the prefix argument is positive, enable the mode, and if it is zero or negative, disable the mode.

If called from Lisp, toggle the mode if ARG is toggle. Enable the mode if ARG is nil, omitted, or is a positive number. Disable the mode if ARG is a negative number.

To check whether the minor mode is enabled in the current buffer, evaluate (default-value \=llama-fontify-mode)'.

The mode's hook is called both when the mode is enabled and when it is disabled.

Key Bindings

Source Code

;; Defined in ~/.emacs.d/elpa/llama-20260301.1253/llama.el
;;;###autoload
(define-minor-mode llama-fontify-mode
  "In Emacs Lisp mode, highlight the `##' macro and its special arguments."
  :lighter llama-fontify-mode-lighter
  :global t
  (cond
    (llama-fontify-mode
     (advice-add 'lisp--el-match-keyword :override
                 #'lisp--el-match-keyword@llama '((depth . -80)))
     (advice-add 'elisp-mode-syntax-propertize :override
                 #'elisp-mode-syntax-propertize@llama)
     (add-hook 'emacs-lisp-mode-hook #'llama--add-font-lock-keywords))
    (t
     (advice-remove 'lisp--el-match-keyword
                    #'lisp--el-match-keyword@llama)
     (advice-remove 'elisp-mode-syntax-propertize
                    #'elisp-mode-syntax-propertize@llama)
     (remove-hook 'emacs-lisp-mode-hook #'llama--add-font-lock-keywords)))
  (dolist (buffer (buffer-list))
    (with-current-buffer buffer
      (when (derived-mode-p 'emacs-lisp-mode)
        (if llama-fontify-mode
            (font-lock-add-keywords  nil llama-font-lock-keywords)
          (font-lock-remove-keywords nil llama-font-lock-keywords))
        (font-lock-flush)))))