Function: magit--set-default-branch

magit--set-default-branch is a byte-compiled function defined in magit-git.el.

Signature

(magit--set-default-branch NEWNAME OLDNAME)

Source Code

;; Defined in ~/.emacs.d/elpa/magit-20260411.1452/magit-git.el
(defun magit--set-default-branch (newname oldname)
  (let ((remote (or (magit-primary-remote)
                    (user-error "Cannot determine primary remote")))
        (branches (mapcar (##split-string % "\t")
                          (magit-git-lines
                           "for-each-ref" "refs/heads"
                           "--format=%(refname:short)\t%(upstream:short)"))))
    (when-let ((old (assoc oldname branches))
               (_(not (assoc newname branches))))
      (magit-call-git "branch" "-m" oldname newname)
      (setcar old newname))
    (let ((new (if (magit-branch-p newname)
                   newname
                 (concat remote "/" newname))))
      (pcase-dolist (`(,branch ,upstream) branches)
        (cond
          ((equal upstream oldname)
           (magit-set-upstream-branch branch new))
          ((equal upstream (concat remote "/" oldname))
           (magit-set-upstream-branch branch (concat remote "/" newname))))))))