Function: magit-log-wash-log

magit-log-wash-log is a byte-compiled function defined in magit-log.el.

Signature

(magit-log-wash-log STYLE ARGS)

Source Code

;; Defined in ~/.emacs.d/elpa/magit-20260411.1452/magit-log.el
(defun magit-log-wash-log (style args)
  (setq args (flatten-tree args))
  (when (if (derived-mode-p 'magit-log-mode)
            magit-log--color-graph
          (and (member "--graph" args)
               (member "--color" args)))
    (let ((ansi-color-apply-face-function
           (lambda (beg end face)
             (put-text-property beg end 'font-lock-face
                                (or face 'magit-log-graph)))))
      (ansi-color-apply-on-region (point-min) (point-max))))
  (when (eq style 'cherry)
    (reverse-region (point-min) (point-max)))
  (let ((magit-log-count 0))
    (when (looking-at "^\\.\\.\\.")
      (magit-delete-line))
    (magit-wash-sequence (apply-partially #'magit-log-wash-rev style
                                          (magit-abbrev-length)))
    (if (derived-mode-p 'magit-log-mode 'magit-reflog-mode)
        (when (eq magit-log-count (magit-log-get-commit-limit))
          (magit-insert-section (longer)
            (insert-text-button
             (substitute-command-keys
              (format "Type \\<%s>\\[%s] to show more history"
                      'magit-log-mode-map
                      'magit-log-double-commit-limit))
             'action (lambda (_button)
                       (magit-log-double-commit-limit))
             'follow-link t
             'mouse-face 'magit-section-highlight)))
      (insert ?\n))))