Function: magit-module-confirm

magit-module-confirm is a byte-compiled function defined in magit-git.el.

Signature

(magit-module-confirm VERB &optional PREDICATE)

Source Code

;; Defined in ~/.emacs.d/elpa/magit-20260411.1452/magit-git.el
(defun magit-module-confirm (verb &optional predicate)
  ;; Some predicates use the inefficient `magit-toplevel'
  ;; and some repositories have thousands of submodules.
  (let ((magit--refresh-cache (list (cons 0 0)))
        (modules nil))
    (cond (current-prefix-arg
           (setq modules (magit-list-module-paths))
           (when predicate
             (setq modules (seq-filter predicate modules)))
           (unless modules
             (if predicate
                 (user-error "No modules satisfying %s available" predicate)
               (user-error "No modules available"))))
          (t
           (setq modules (magit-region-values 'module))
           (when modules
             (when predicate
               (setq modules (seq-filter predicate modules)))
             (unless modules
               (user-error "No modules satisfying %s selected" predicate)))))
    (if (or (length> modules 1) current-prefix-arg)
        (magit-confirm t nil (format "%s %%d modules" verb) nil modules)
      (list (magit-read-module-path (format "%s module" verb) predicate)))))