Function: mh-alias-letter-expand-alias

mh-alias-letter-expand-alias is an autoloaded and byte-compiled function defined in mh-alias.el.gz.

Signature

(mh-alias-letter-expand-alias)

Documentation

Expand mail alias before point.

Source Code

;; Defined in /usr/src/emacs/lisp/mh-e/mh-alias.el.gz
;;;###mh-autoload
(defun mh-alias-letter-expand-alias ()
  "Expand mail alias before point."
  (mh-alias-reload-maybe)
  (let* ((begin (mh-beginning-of-word))
         (end (save-excursion
                (goto-char begin)
                (mh-beginning-of-word -1))))
    (when (>= end (point))
      (list
       begin (if (fboundp 'completion-at-point) end (point))
       (if (not mh-alias-expand-aliases-flag)
           mh-alias-alist
         (lambda (string pred action)
           (cl-case action
             ((nil)
              (let ((res (try-completion string mh-alias-alist pred)))
                (if (or (eq res t)
                        (and (stringp res)
                             (eq t (try-completion res mh-alias-alist pred))))
                    (or (mh-alias-expand (if (stringp res) res string))
                        res)
                  res)))
             ((t) (all-completions string mh-alias-alist pred))
             ((lambda) (mh-test-completion string mh-alias-alist pred)))))))))