Function: mh-identity-make-menu

mh-identity-make-menu is an autoloaded and byte-compiled function defined in mh-identity.el.gz.

Signature

(mh-identity-make-menu)

Documentation

Build the Identity menu.

This should be called any time mh-identity-list or mh-auto-fields-list change. See mh-identity-add-menu.

Aliases

mh-identity-make-menu-no-autoload

Source Code

;; Defined in /usr/src/emacs/lisp/mh-e/mh-identity.el.gz
;;;###mh-autoload
(defun mh-identity-make-menu ()
  "Build the Identity menu.
This should be called any time `mh-identity-list' or
`mh-auto-fields-list' change.
See `mh-identity-add-menu'."
  (easy-menu-define mh-identity-menu mh-letter-mode-map
    "MH-E identity menu"
    (append
     '("Identity")
     ;; Dynamically render :type corresponding to `mh-identity-list'
     ;; e.g.:
     ;;  ["Home" (mh-insert-identity "Home")
     ;;   :style radio :active (not (equal mh-identity-local "Home"))
     ;;   :selected (equal mh-identity-local "Home")]
     '(["Insert Auto Fields"
        (mh-insert-auto-fields) mh-auto-fields-list]
       "--")

     (mapcar (lambda (arg)
               `[,arg  (mh-insert-identity ,arg) :style radio
                       :selected (equal mh-identity-local ,arg)])
             (mapcar #'car mh-identity-list))
     '(["None"
        (mh-insert-identity "None") :style radio
        :selected (not mh-identity-local)]
       "--"
       ["Set Default for Session"
        (setq mh-identity-default mh-identity-local) t]
       ["Save as Default"
        (customize-save-variable 'mh-identity-default mh-identity-local) t]
       ["Customize Identities" (customize-variable 'mh-identity-list) t]
       ))))