Function: mm-inline-message

mm-inline-message is a byte-compiled function defined in mm-view.el.gz.

Signature

(mm-inline-message HANDLE)

Documentation

Insert HANDLE (a message/rfc822 part) into the current buffer.

This function will call mm-inline-message-prepare-function after inserting the part.

Source Code

;; Defined in /usr/src/emacs/lisp/gnus/mm-view.el.gz
(defun mm-inline-message (handle)
  "Insert HANDLE (a message/rfc822 part) into the current buffer.
This function will call `mm-inline-message-prepare-function'
after inserting the part."
  (let ((b (point))
	(bolp (bolp))
	(charset (mail-content-type-get
		  (mm-handle-type handle) 'charset)))
    (when (and charset
	       (stringp charset))
      (setq charset (intern (downcase charset)))
      (when (eq charset 'us-ascii)
	(setq charset nil)))
    (save-excursion
      (save-restriction
	(narrow-to-region b b)
	(mm-insert-part handle)
        (when mm-inline-message-prepare-function
	  (funcall mm-inline-message-prepare-function handle charset))
	(goto-char (point-min))
	(unless bolp
	  (insert "\n"))
	(goto-char (point-max))
	(unless (bolp)
	  (insert "\n"))
	(insert "----------\n\n")
	(mm-handle-set-undisplayer
	 handle
	 (let ((beg (point-min-marker))
	       (end (point-max-marker)))
	   (lambda ()
	     (let ((inhibit-read-only t))
	       (delete-region beg end)))))))))