Function: mml-content-disposition

mml-content-disposition is a byte-compiled function defined in mml.el.gz.

Signature

(mml-content-disposition TYPE &optional FILENAME)

Documentation

Return a default disposition name suitable to TYPE or FILENAME.

Source Code

;; Defined in /usr/src/emacs/lisp/gnus/mml.el.gz
(defun mml-content-disposition (type &optional filename)
  "Return a default disposition name suitable to TYPE or FILENAME."
  (let ((defs mml-content-disposition-alist)
	disposition def types)
    (while (and (not disposition) defs)
      (setq def (pop defs))
      (cond ((stringp (car def))
	     (when (and filename
			(string-match (car def) filename))
	       (setq disposition (cdr def))))
	    ((consp (cdr def))
	     (when (string= (car (setq types (split-string type "/")))
			    (car def))
	       (setq type (cadr types)
		     types (cdr def))
	       (while (and (not disposition) types)
		 (setq def (pop types))
		 (when (or (eq (car def) t) (string= type (car def)))
		   (setq disposition (cdr def))))))
	    (t
	     (when (or (eq (car def) t) (string= type (car def)))
	       (setq disposition (cdr def))))))
    (or disposition "attachment")))