Function: mml2015-epg-sign

mml2015-epg-sign is a byte-compiled function defined in mml2015.el.gz.

Signature

(mml2015-epg-sign CONT)

Source Code

;; Defined in /usr/src/emacs/lisp/gnus/mml2015.el.gz
(defun mml2015-epg-sign (cont)
  (let ((boundary (mml-compute-boundary cont)))
    ;; Signed data must end with a newline (RFC 3156, 5).
    (goto-char (point-max))
    (unless (bolp)
      (insert "\n"))
    (let* ((pair (mml-secure-epg-sign 'OpenPGP t))
	   (signature (car pair))
	   (micalg (cdr pair)))
      (unless (stringp signature)
        (error "Signature failed"))
      (goto-char (point-min))
      (insert (format "Content-Type: multipart/signed; boundary=\"%s\";\n"
		      boundary))
      (if micalg
	  (insert (format "\tmicalg=pgp-%s; "
			  (downcase
			   (cdr (assq micalg
				      epg-digest-algorithm-alist))))))
      (insert "protocol=\"application/pgp-signature\"\n")
      (insert (format "\n--%s\n" boundary))
      (goto-char (point-max))
      (insert (format "\n--%s\n" boundary))
      (insert "Content-Type: application/pgp-signature; name=\"signature.asc\"\n\n")
      (insert signature)
      (goto-char (point-max))
      (insert (format "--%s--\n" boundary))
      (goto-char (point-max)))))