Function: nndoc-set-delims

nndoc-set-delims is a byte-compiled function defined in nndoc.el.gz.

Signature

(nndoc-set-delims)

Documentation

Set the nndoc delimiter variables according to the type of the document.

Source Code

;; Defined in /usr/src/emacs/lisp/gnus/nndoc.el.gz
;;;
;;; Deciding what document type we have
;;;

(defun nndoc-set-delims ()
  "Set the nndoc delimiter variables according to the type of the document."
  (let ((vars '(nndoc-file-begin
		nndoc-first-article
		nndoc-article-begin-function
		nndoc-head-begin nndoc-head-end
		nndoc-file-end nndoc-article-begin
		nndoc-body-begin nndoc-body-end-function nndoc-body-end
		nndoc-prepare-body-function nndoc-article-transform-function
		nndoc-header-transform-function
		nndoc-generate-head-function nndoc-body-begin-function
		nndoc-head-begin-function
		nndoc-generate-article-function
		nndoc-dissection-function
		nndoc-pre-dissection-function)))
    (while vars
      (set (pop vars) nil)))
  (let (defs)
    ;; Guess away until we find the real file type.
    (while (assq 'guess (setq defs (cdr (assq nndoc-article-type
					      nndoc-type-alist))))
      (setq nndoc-article-type (nndoc-guess-type nndoc-article-type)))
    ;; Set the nndoc variables.
    (while defs
      (set (intern (format "nndoc-%s" (caar defs)))
	   (cdr (pop defs))))))