Function: nnmail-expired-article-p

nnmail-expired-article-p is a byte-compiled function defined in nnmail.el.gz.

Signature

(nnmail-expired-article-p GROUP TIME FORCE &optional INHIBIT)

Documentation

Say whether an article that is TIME old in GROUP should be expired.

If TIME is nil, then return the cutoff time for oldness instead.

Source Code

;; Defined in /usr/src/emacs/lisp/gnus/nnmail.el.gz
(defun nnmail-expired-article-p (group time force &optional inhibit)
  "Say whether an article that is TIME old in GROUP should be expired.
If TIME is nil, then return the cutoff time for oldness instead."
  (if force
      (if (null time)
	  (current-time)
	t)
    (let ((days (or (and nnmail-expiry-wait-function
			 (funcall nnmail-expiry-wait-function group))
		    nnmail-expiry-wait)))
      (cond ((or (eq days 'never)
		 (and (not force)
		      inhibit))
	     ;; This isn't an expirable group.
	     nil)
	    ((eq days 'immediate)
	     ;; We expire all articles on sight.
	     (if (null time)
		 (current-time)
	       t))
	    ((equal time '(0 0))
	    ;; This is an ange-ftp group, and we don't have any dates.
	     nil)
	    ((numberp days)
	     (setq days (days-to-time days))
	     ;; Compare the time with the current time.
	     (if (null time)
		 (time-since days)
	       (ignore-errors (time-less-p days (time-since time)))))))))