Function: nnmbox-find-article

nnmbox-find-article is a byte-compiled function defined in nnmbox.el.gz.

Signature

(nnmbox-find-article ARTICLE)

Documentation

Leaves point on the relevant X-Gnus-Newsgroup line if found.

Source Code

;; Defined in /usr/src/emacs/lisp/gnus/nnmbox.el.gz
(defun nnmbox-find-article (article)
  "Leaves point on the relevant X-Gnus-Newsgroup line if found."
  ;; Check that article is in the active range first, to avoid an
  ;; expensive exhaustive search if it isn't.
  (if (and (numberp article)
	   (not (nnmbox-is-article-active-p article)))
      nil
    (let ((art-string (nnmbox-article-string article))
	  (found nil))
      ;; There is the possibility that the X-Gnus-Newsgroup line appears
      ;; in the body of an article (for instance, if an article has been
      ;; forwarded from someone using Gnus as their mailer), so check
      ;; that the line is actually part of the article header.
      (or (and (search-forward art-string nil t)
	       (nnmbox-in-header-p (point)))
	  (progn
	    (goto-char (point-min))
	    (while (and (not found)
			(search-forward art-string nil t))
	      (setq found (nnmbox-in-header-p (point))))
	    found)))))