Function: octave-find-definition-default-filename

octave-find-definition-default-filename is a byte-compiled function defined in octave.el.gz.

Signature

(octave-find-definition-default-filename NAME)

Documentation

Default value for octave-find-definition-filename-function.

Source Code

;; Defined in /usr/src/emacs/lisp/progmodes/octave.el.gz
(defun octave-find-definition-default-filename (name)
  "Default value for `octave-find-definition-filename-function'."
  (pcase (file-name-extension name)
    ("oct"
     (octave-find-definition-default-filename
      (concat "libinterp/dldfcn/"
              (file-name-sans-extension (file-name-nondirectory name))
              ".cc")))
    ("cc"
     (let ((file (or (locate-file name (octave-source-directories))
                     (locate-file (file-name-nondirectory name)
                                  (octave-source-directories)))))
       (or (and file (file-exists-p file))
           (error "File `%s' not found" name))
       file))
    ("mex"
     (if (yes-or-no-p (format-message "File `%s' may be binary; open? "
				      (file-name-nondirectory name)))
         name
       (user-error "Aborted")))
    (_ name)))