Function: preview-create-subdirectory

preview-create-subdirectory is a byte-compiled function defined in preview.el.

Signature

(preview-create-subdirectory)

Documentation

Create a temporary subdir for the current TeX process.

If necessary, generates a fitting top directory or cleans out an existing one (if not yet visited in this session), then returns the name of the created subdirectory relative to the master directory, in shell-quoted form. TeX-active-tempdir is set to the corresponding TEMPDIR descriptor as described in preview-make-filename. The directory is registered in preview-temp-dirs in order not to be cleaned out later while in use.

Source Code

;; Defined in ~/.emacs.d/elpa/auctex-14.1.2/preview.el
(defun preview-create-subdirectory ()
  "Create a temporary subdir for the current TeX process.
If necessary, generates a fitting top
directory or cleans out an existing one (if not yet
visited in this session), then returns the name of
the created subdirectory relative to the master directory,
in shell-quoted form.  `TeX-active-tempdir' is
set to the corresponding TEMPDIR descriptor as described
in `preview-make-filename'.  The directory is registered
in `preview-temp-dirs' in order not to be cleaned out
later while in use."
  (let ((topdir (expand-file-name (TeX-active-master "prv"))))
    (if (file-directory-p topdir)
        (unless (member topdir preview-temp-dirs)
          ;;  Cleans out the top preview directory by
          ;;  removing subdirs possibly left from a previous session.
          (preview-clean-topdir topdir)
          (push topdir preview-temp-dirs))
      (make-directory topdir)
      (add-to-list 'preview-temp-dirs topdir))
    (add-hook 'kill-emacs-hook #'preview-cleanout-tempfiles t)
    (setq TeX-active-tempdir
          (list (make-temp-file (expand-file-name
                                 "tmp" (file-name-as-directory topdir)) t)
                topdir
                0))
    (shell-quote-argument
     (concat (file-name-as-directory
              ;; Don't use topdir, because %m expects the path to be
              ;; relative to master
              (TeX-active-master "prv" t))
             (file-name-nondirectory (nth 0 TeX-active-tempdir))))))