Function: ps-print-preprint

ps-print-preprint is an autoloaded and byte-compiled function defined in ps-print.el.gz.

Signature

(ps-print-preprint PREFIX)

Source Code

;; Defined in /usr/src/emacs/lisp/ps-print.el.gz
(defun ps-print-preprint (prefix)
  (and prefix
       (or (numberp prefix)
	   (listp prefix))
       (let* ((name   (concat (file-name-nondirectory (or (buffer-file-name)
							  (buffer-name)))
			      ".ps"))
	      (prompt (format-prompt "Save PostScript to file" name))
	      (res    (read-file-name prompt default-directory name nil)))
	 (while (cond ((file-directory-p res)
		       (ding)
		       (setq prompt "It's a directory"))
		      ((not (file-writable-p res))
		       (ding)
		       (setq prompt "File is unwritable"))
		      ((file-exists-p res)
		       (setq prompt "File exists")
		       (not (y-or-n-p (format-message
				       "File `%s' exists; overwrite? " res))))
		      (t nil))
	   (setq res (read-file-name
		      (format "%s; save PostScript to file: " prompt)
		      (file-name-directory res) nil nil
		      (file-name-nondirectory res))))
	 (if (file-directory-p res)
	     (expand-file-name name (file-name-as-directory res))
	   res))))