Function: rmail-unknown-mail-followup-to

rmail-unknown-mail-followup-to is a byte-compiled function defined in rmail.el.gz.

Signature

(rmail-unknown-mail-followup-to)

Documentation

Handle a "Mail-Followup-To" header field with an unknown mailing list.

Ask the user whether to add that list name to mail-mailing-lists.

Source Code

;; Defined in /usr/src/emacs/lisp/mail/rmail.el.gz
(defun rmail-unknown-mail-followup-to ()
  "Handle a \"Mail-Followup-To\" header field with an unknown mailing list.
Ask the user whether to add that list name to `mail-mailing-lists'."
  ;; FIXME s-r not needed?  Use rmail-get-header?
  ;; We have not narrowed to the headers at ths point?
   (save-restriction
     (let ((mail-followup-to (mail-fetch-field "mail-followup-to" nil t)))
       (when mail-followup-to
	 (let ((addresses
		(split-string
		 (mail-strip-quoted-names mail-followup-to)
		 ",[[:space:]]+" t)))
	   (dolist (addr addresses)
	     (when (and (not (member addr mail-mailing-lists))
			(not
			 ;; taken from rmailsum.el
			 (string-match
			  (or rmail-user-mail-address-regexp
			      (concat "^\\("
				      (regexp-quote (user-login-name))
				      "\\($\\|@\\)\\|"
				      (regexp-quote user-mail-address)
				      "\\>\\)"))
			  addr))
			(y-or-n-p
			 (format-message "Add `%s' to `mail-mailing-lists'? "
					 addr)))
	       (customize-save-variable 'mail-mailing-lists
					(cons addr mail-mailing-lists)))))))))