Function: skkdic-convert-prefix

skkdic-convert-prefix is a byte-compiled function defined in ja-dic-cnv.el.gz.

Signature

(skkdic-convert-prefix SKKBUF BUF)

Source Code

;; Defined in /usr/src/emacs/lisp/international/ja-dic-cnv.el.gz
(defun skkdic-convert-prefix (_skkbuf buf)
  (byte-compile-info "Processing PREFIX entries" t)
  (goto-char (point-min))
  (with-current-buffer buf
    (insert ";; Setting prefix entries.\n"
	    "(skkdic-set-prefix\n"))
  (save-excursion
    (while (re-search-forward "^\\(\\cH+\\)[<>?] " nil t)
      (let ((kana (match-string-no-properties 1))
	    str candidates)
	(while (looking-at "/\\([^/\n]+\\)/")
          (setq str (match-string-no-properties 1))
	  (if (not (member str candidates))
	      (setq candidates (cons str candidates)))
	  (goto-char (match-end 1)))
	(with-current-buffer buf
	  (insert "\"" kana)
	  (while candidates
	    (insert " " (car candidates))
	    (set-nested-alist (car candidates) kana skkdic-prefix-list)
	    (setq candidates (cdr candidates)))
	  (insert "\"\n")))))
  (with-current-buffer buf
    (insert ")\n\n")))