Function: table--spacify-frame

table--spacify-frame is a byte-compiled function defined in table.el.gz.

Signature

(table--spacify-frame)

Documentation

Spacify table frame.

Replace frame characters with spaces.

Source Code

;; Defined in /usr/src/emacs/lisp/textmodes/table.el.gz
(defun table--spacify-frame ()
  "Spacify table frame.
Replace frame characters with spaces."
  (let ((frame-char
         (append (string-to-list table-cell-horizontal-chars)
                 (list table-cell-intersection-char table-cell-vertical-char))))
    (while
	(progn
	  (cond
	   ((eq (char-after) table-cell-intersection-char)
	    (save-excursion
	      (let ((col (current-column)))
		(and (zerop (forward-line 1))
		     (zerop (current-column))
		     (move-to-column col)
		     (table--spacify-frame))))
	    (delete-char 1)
	    (insert-before-markers ?\s))
	   ((table--cell-horizontal-char-p (char-after))
	    (while (progn
		     (delete-char 1)
		     (insert-before-markers ?\s)
		     (table--cell-horizontal-char-p (char-after)))))
	   ((eq (char-after) table-cell-vertical-char)
	    (while (let ((col (current-column)))
		     (delete-char 1)
		     (insert-before-markers ?\s)
		     (and (zerop (forward-line 1))
			  (zerop (current-column))
			  (move-to-column col)
			  (eq (char-after) table-cell-vertical-char))))))
	  (memq (char-after) frame-char)))))