Function: tpu-load-xkeys

tpu-load-xkeys is an interactive and byte-compiled function defined in tpu-edt.el.gz.

Signature

(tpu-load-xkeys FILE)

Documentation

Load the TPU-edt X-windows key definitions FILE.

If FILE is nil, try to load a default file. The default file names are
~/.tpu-lucid-keys for XEmacs, and ~/.tpu-keys for Emacs.

Key Bindings

Source Code

;; Defined in /usr/src/emacs/lisp/obsolete/tpu-edt.el.gz
;;;
;;;  Emacs version 19 X-windows key definition support
;;;
(defun tpu-load-xkeys (file)
  "Load the TPU-edt X-windows key definitions FILE.
If FILE is nil, try to load a default file.  The default file names are
`~/.tpu-lucid-keys' for XEmacs, and `~/.tpu-keys' for Emacs."
  (interactive "fX key definition file: ")
  (cond (file
	 (setq file (expand-file-name file)))
	(tpu-xkeys-file
	 (setq file (expand-file-name tpu-xkeys-file)))
	((featurep 'xemacs)
	 (setq file (convert-standard-filename
		     (expand-file-name "~/.tpu-lucid-keys"))))
	(t
	 (setq file (convert-standard-filename
		     (expand-file-name "~/.tpu-keys")))
	 (and (not (file-exists-p file))
	      (file-exists-p
	       (convert-standard-filename
		(expand-file-name "~/.tpu-gnu-keys")))
	      (tpu-copy-keyfile
	       (convert-standard-filename
		(expand-file-name "~/.tpu-gnu-keys")) file))))
  (cond ((file-readable-p file)
	 (load-file file))
	(t
         ;; This used to force the user to build `file'.  With the
         ;; new code, such a file may not be necessary.  In case it
         ;; is, issue a message giving a hint as to how to build it.
         (message "%s not found: use M-x tpu-mapper to create it"
                  (abbreviate-file-name file)))))