Function: url-http--user-agent-default-string

url-http--user-agent-default-string is a byte-compiled function defined in url-http.el.gz.

Signature

(url-http--user-agent-default-string)

Documentation

Compute a default User-Agent string based on url-privacy-level.

Source Code

;; Defined in /usr/src/emacs/lisp/url/url-http.el.gz
(defun url-http--user-agent-default-string ()
  "Compute a default User-Agent string based on `url-privacy-level'."
  (let ((package-info (when url-package-name
                        (format "%s/%s" url-package-name url-package-version)))
        (emacs-info (unless (and (listp url-privacy-level)
                                 (memq 'emacs url-privacy-level))
                      (format "Emacs/%s" emacs-version)))
        (os-info (unless (and (listp url-privacy-level)
                              (memq 'os url-privacy-level))
                   (format "(%s; %s)" url-system-type url-os-type)))
        (url-info "URL/Emacs"))
    (string-join (delq nil (list package-info url-info
                                 emacs-info os-info))
                 " ")))