Function: woman1-roff-buffer

woman1-roff-buffer is a byte-compiled function defined in woman.el.gz.

Signature

(woman1-roff-buffer)

Documentation

Process non-breaking requests.

Source Code

;; Defined in /usr/src/emacs/lisp/woman.el.gz
(defvar woman1-unquote)          ; bound locally by woman1-roff-buffer

(defun woman1-roff-buffer ()
  "Process non-breaking requests."
  (let ((case-fold-search t)
	woman-request fn woman1-unquote)
    (while
	;; Find next control line:
	(re-search-forward woman-request-regexp nil t)
      (cond
       ;; Construct woman function to call:
       ((setq fn (intern-soft
		  (concat "woman1-"
			  (setq woman-request (match-string 1)))))
	(if (get fn 'notfont)		; not a font-change request
	    (funcall fn)
	  ;; Delete request or macro name:
	  (woman-delete-match 0)
	  ;; If no args then apply to next line else unquote args
	  ;; (woman1-unquote is used by called function):
	  (setq woman1-unquote (not (eolp)))
	  (if (eolp) (delete-char 1))
;	    ;; Hide leading control character in unquoted argument:
;	    (cond ((memq (following-char) '(?. ?'))
;		   (insert "\\&")
;		   (beginning-of-line)))
	  ;; Call the appropriate function:
	  (funcall fn)
	  ;; Hide leading control character in quoted argument (only):
	  (if (and woman1-unquote (memq (following-char) '(?. ?')))
	      (insert "\\&"))))))))