Function: TeX-ConTeXt-sentinel

TeX-ConTeXt-sentinel is a byte-compiled function defined in context.el.

Signature

(TeX-ConTeXt-sentinel PROCESS NAME)

Documentation

Examine the TeX output buffer after running ConTeXt.

Parse the output buffer to collect errors and warnings if the variable TeX-parse-all-errors(var)/TeX-parse-all-errors(fun) is non-nil.

Open the error overview if TeX-error-overview-open-after-TeX-run is non-nil and there are errors or warnings to show.

Source Code

;; Defined in ~/.emacs.d/elpa/auctex-14.2.0/context.el
(defun TeX-ConTeXt-sentinel (process name)
  "Examine the TeX output buffer after running ConTeXt.

Parse the output buffer to collect errors and warnings if the
variable `TeX-parse-all-errors' is non-nil.

Open the error overview if
`TeX-error-overview-open-after-TeX-run' is non-nil and there are
errors or warnings to show."

  (if (TeX-ConTeXt-sentinel-check process name)
      (progn
        ;; ConTeXt LMTX stops after 1 error (unless "heroic" efforts are
        ;; made by the user to do otherwise) and if such efforts are made
        ;; the error messages in the log file are not complete (at least
        ;; as of ConTeXt Version 2026.02.12).  Arguably it might make
        ;; sense to just call (TeX-parse-error) once (and set the other
        ;; variables as seen in (TeX-parse-all-errors)).  But for now, ...
        (if TeX-parse-all-errors
            (TeX-parse-all-errors))
        (if (and (with-current-buffer TeX-command-buffer
                   TeX-error-overview-open-after-TeX-run)
                 (TeX-error-overview-make-entries
                  (TeX-master-directory) (TeX-active-buffer)))
            (TeX-error-overview)))

    (message (concat name ": formatted " (TeX-current-pages)))
    (setq TeX-command-next TeX-command-Show))
  (unless TeX-error-list
    (run-hook-with-args 'TeX-after-compilation-finished-functions
                        (with-current-buffer TeX-command-buffer
                          (expand-file-name
                           (TeX-active-master (TeX-output-extension)))))))