Function: TeX-submit-bug-report

TeX-submit-bug-report is an autoloaded, interactive and byte-compiled function defined in tex.el.

Signature

(TeX-submit-bug-report)

Documentation

Submit a bug report on AUCTeX via mail.

Don't hesitate to report any problems or inaccurate documentation.

If you don't have setup sending mail from Emacs, please copy the output buffer into your mail program, as it gives us important information about your AUCTeX version and AUCTeX configuration.

Key Bindings

Source Code

;; Defined in ~/.emacs.d/elpa/auctex-14.1.2/tex.el
;;;###autoload
(defun TeX-submit-bug-report ()
  "Submit a bug report on AUCTeX via mail.

Don't hesitate to report any problems or inaccurate documentation.

If you don't have setup sending mail from Emacs, please copy the
output buffer into your mail program, as it gives us important
information about your AUCTeX version and AUCTeX configuration."
  (interactive)
  (require 'reporter)
  (defvar reporter-prompt-for-summary-p)
  (let ((reporter-prompt-for-summary-p "Bug report subject: "))
    (reporter-submit-bug-report
     "bug-auctex@gnu.org"
     AUCTeX-version
     (list 'window-system
           'LaTeX-version
           'TeX-style-path
           'TeX-auto-save
           'TeX-parse-self
           'TeX-master
           'TeX-command-list)
     nil
     ;; reporter adds too many new lines around salutation text, that we don't
     ;; want, since it's itself a new line.
     (lambda ()
       (save-excursion
         (goto-char (point-min))
         (re-search-forward mail-header-separator)
         (forward-char)
         (delete-char 1)
         (forward-char)
         (delete-char 2)))
     (propertize
      "\n" 'display
      (with-temp-buffer
        (insert
         "Remember to cover the basics, that is, what you expected to happen and
what in fact did happen.

Be sure to consult the FAQ section in the manual before submitting
a bug report.  In addition check if the bug is reproducable with an
up-to-date version of AUCTeX.  So please upgrade to the version
available from ")
        (insert-text-button
         "https://www.gnu.org/software/auctex/"
         'face 'link
         'help-echo (concat "mouse-2, RET: Follow this link")
         'action (lambda (_button)
                   (browse-url "https://www.gnu.org/software/auctex/"))
         'follow-link t)
        (insert " if your
installation is older than the one available from the web site.

If the bug is triggered by a specific (La)TeX file, you should try
to produce a minimal sample file showing the problem and include it
in your report.

Your report will be posted for the auctex package at the GNU bug
tracker.  Visit ")
        (insert-text-button
         "https://debbugs.gnu.org/cgi/pkgreport.cgi?pkg=auctex"
         'face 'link
         'help-echo (concat "mouse-2, RET: Follow this link")
         'action (lambda (_button)
                   (browse-url "https://debbugs.gnu.org/cgi/pkgreport.cgi?pkg=auctex"))
         'follow-link t)
        (insert "\nto browse existing AUCTeX bugs.
------------------------------------------------------------------------\n\n")
        (buffer-string))))))