Function: artist-compute-key-compl-table

artist-compute-key-compl-table is a byte-compiled function defined in artist.el.gz.

Signature

(artist-compute-key-compl-table MENU-TABLE)

Documentation

Compute completion table from MENU-TABLE, suitable for completing-read.

Source Code

;; Defined in /usr/src/emacs/lisp/textmodes/artist.el.gz
;
; Computing the completion table from the master table
;

(defun artist-compute-key-compl-table (menu-table)
  "Compute completion table from MENU-TABLE, suitable for `completing-read'."
  (apply
   'nconc
   (remq nil
    (mapcar
     (lambda (element)
       (let ((element-tag (artist-mt-get-tag element)))
	 (cond ((eq element-tag 'graphics-operation)
		(let* ((info-part     (artist-mt-get-info-part element))
		       (unshifted     (artist-go-get-unshifted info-part))
		       (shifted       (artist-go-get-shifted info-part))
		       (unshifted-kwd (artist-go-get-keyword unshifted))
		       (shifted-kwd   (artist-go-get-keyword shifted)))
		  (list (list unshifted-kwd) (list shifted-kwd))))
	       ((eq element-tag 'menu)
		(let* ((info-part     (artist-mt-get-info-part element))
		       (items         (artist-mn-get-items info-part)))
		  (artist-compute-key-compl-table items)))
	       (t
		nil))))
     menu-table))))